home *** CD-ROM | disk | FTP | other *** search
/ Tiger Disk 18 / Tiger_Disk_018_19xx_Tiger-Crew-Disk_de_Side_A.d64 / sort. directory (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  2KB  |  68 lines
  1. 10 rem * sortiertes directory *
  2. 20 poke53281,11:poke53280,11:poke53272,21:print"[147][159]"
  3. 30 ifzz=999then380
  4. 40 zz=999
  5. 50 printtab(10)"sortiertes directory"
  6. 60 printtab(10)"--------------------"
  7. 70 printtab(17)"moment"
  8. 80 printtab(12)"daten werden von"
  9. 90 printtab(12)"diskette gelesen"
  10. 100 printtab(12)"und sortiert !!!"
  11. 110 open8,8,0,"$":open4,4,0:g$=chr$(34):bl$=" ":p$=chr$(9)
  12. 120 dimd$(128),f$(128),d%(128),g%(128):n=-1
  13. 130 get#8,a$:ifa$=""then230
  14. 140 n=n+1:get#8,a$:get#8,a$:get#8,b$:ifa$<>""theng%(n)=asc(a$)
  15. 150 ifb$<>""theng%(n)=g%(n)+asc(b$)*256
  16. 160 get#8,a$:ifa$=""andn<>0then230
  17. 170 ifa$<>g$then160
  18. 180 get#8,a$:ifa$<>g$thend$(n)=d$(n)+a$:goto180
  19. 190 get#8,a$:ifa$=bl$then190
  20. 200 f$(n)=a$
  21. 210 get#8,a$:ifa$<>""then210
  22. 220 goto130
  23. 230 n=n-1:close8:fori=1ton:d%(i)=i:next
  24. 240 l=int((n)/2)+1:r=n
  25. 250 ifl>1then290
  26. 260 ifr<=1then280
  27. 270 h=d%(l):d%(l)=d%(r):d%(r)=h:r=r-1
  28. 280 goto300
  29. 290 l=l-1
  30. 300 i=l:j=2*i:h=d%(i):h$=d$(h):ifj>rthen370
  31. 310 ifj>=rthen340
  32. 320 ifd$(d%(j))>=d$(d%(j+1))then340
  33. 330 j=j+1
  34. 340 ifj>rthen370
  35. 350 ifh$>=d$(d%(j))then370
  36. 360 d%(i)=d%(j):i=j:j=2*i:goto310
  37. 370 d%(i)=h:ifr<>1then250
  38. 380 z=1:a=1:b=21:ifb>nthenb=n
  39. 390 gosub540:print"     "d$(0)"[146]"
  40. 400 fori=atob:printg%(d%(i))tab(5)d$(d%(i))tab(23)f$(d%(i)):next
  41. 410 print""g%(n+1);"[146] freie bloecke";
  42. 420 geta$:ifa$=""then420
  43. 430 x=asc(a$)-132:ifx<1orx>4then420
  44. 440 onxgoto450,480,500,510
  45. 450 a=a-20:ifa<1thena=1
  46. 460 b=a+20:ifb>nthenb=n
  47. 470 goto390
  48. 480 a=a+20:ifa>nthena=n
  49. 490 goto460
  50. 500 print"[147]tschuess":end
  51. 510 print#4,chr$(14)d$(0):print#4,chr$(27);"d";chr$(6);chr$(26);chr$(0)
  52. 520 fori=1ton:gg$=str$(g%(d%(i))):print#4,gg$spc(5-len(gg$))p$d$(d%(i));
  53. 525 print#4,spc(20-len(d$(d%(i))))p$f$(d%(i)):next
  54. 530 print#4:print#4,g%(n+1)" bloecke frei":print#4:goto420
  55. 540 print"[147]"
  56. 550 printtab(32)"f1[146]"
  57. 560 printtab(28)"rueckwaerts"
  58. 570 printtab(29)"blaettern"
  59. 580 printtab(32)"f3"
  60. 590 printtab(29)"vorwaerts"
  61. 600 printtab(29)"blaettern"
  62. 610 printtab(32)"f5"
  63. 620 printtab(31)"ende"
  64. 630 printtab(32)"f7"
  65. 640 printtab(30)"ausgabe"
  66. 650 printtab(30)"drucker"
  67. 660 return
  68.